Gammon Forum

sub ClanChan(tname, output, wilds)
  'First lets get the number of lines we are keeping.
  dim Keep
  Keep = world.getvariable("ClanKeep")
  'Retrieve last traffic.
  dim Buffer
  Buffer = split(world.getvariable("ClanChan"),",")
  'Find a blank spot, if there is one.
  dim count, fnd
  fnd = -1
  for count = 0 to Keep
    if Buffer(count) = "-1" or Buffer(count) = "Empty" then
      fnd = count
      exit for
    end if
  next
  if fnd = -1 then
    'We already have the maximum, so shift them all and add the new on into
    'the last possition.
    for count = 1 to Keep
      Buffer(count - 1) = Buffer(count)
    next
    'Note: We use 'now' to get the time and date to time stamp it. ;)
    Buffer(Keep) = now & " " & wilds(1)
  else
    'This is if we found a blank.
    Buffer(fnd) = now & " " & wilds(1)
  end if
  world.setvariable "ClanChan", join(Buffer,",")
end sub

sub SetClanBuffer (aname, output, wilds)
  dim Keep
  Keep = wilds(1)
  if isnumeric(Keep) then
    if Keep < 2 then
      world.note "Clan buffer cannot be less than two lines."
    else
      'Since arrays start at 0, we need one less than our setting or 10 lines would end up as 11.
      Keep = Keep - 1
    end if
    'Retrieve last traffic.
    dim Buffer
    Buffer = split(world.getvariable("ClanChan"),",")
    if Keep > ubound(Buffer) then
      'We will need a new array, since split does not create one you can change the size of. :p
      dim NewAr(Keep)
      dim count
      'Put existing data in the new one.
      for count = 0 to unbound(Buffer)
        NewAr(count) = Buffer(count)
      next
      'Fill the rest.
      for count = ubound(Buffer) + 1 to Keep
        NewAr(count) = "-1"
      next
      world.setvariable "ClanChan", join(NewAr,",")
    else
      if Keep = ubound(Buffer) then
        world.note "New size for clan buffer is the same as last."
        world.note "Command ignored."
        exit sub
      end if
      'We will need a new array, since split does not create one you can change the size of. :p
      dim NewAr(Keep)        
      dim count, oldlen, strt
      oldlen = ubound(Buffer)
      strt = oldlen - Keep
      'Store what we can.
      for count =  strt to oldlen
        NewAr(count - strt) = Buffer(count)
      next
      world.setvariable "ClanChan", join(NewAr,",")
    end if
    world.note Keep & "lines of clan messages will now be stored."
  else
    world.note "Must be a number! >" & Keep & "<"
  end if
end sub

sub ShowClan(aname, output, wilds)
  dim Buffer, count
  Buffer = split(world.getvariable("ClanChan"),",")
  for count = 0 to ubound(Buffer)
    if Buffer(count) <> "-1" then
      world.note "[CLAN]: " & Buffer(count)
    end if
  next
end sub

Now..

Trigger - 
  Match: '[CLAN]: *'
  Name: ClanChan
  Script: ClanChan

Alias 1 -
  Match: Showclan
  Name: Showclan
  Script: Showclan

Alias 2 -
  Match: Clanset *
  Name: Clanset
  Script: SetClanBuffer

I would also suggest that this be in a plugin and you add the following:

sub OnPluginInstall
  dim Keep
  Keep = world.getvariable("Keep")
  if isnumber(Keep) and Keep > 0 then
    exit sub
  end if
  world.setvariable "Keep" , "10"
  world.setvariable "ClanChan", "Empty,-1,-1,-1,-1,-1,-1,-1,-1,-1"
end sub

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE muclient>
<!-- Saved on Saturday, January 04, 2003, 11:44 AM -->
<!-- MuClient version 3.32 -->

<!-- Plugin "ClanChan" generated by Plugin Wizard -->

<muclient>
<plugin
   name="ClanChan"
   author="kagehi"
   id="47c87a3b66afba3264f8fc23"
   language="VBscript"
   save_state="y"
   date_written="2003-01-04 11:43:32"
   requires="3.32"
   version="1.0"
   >

</plugin>


<!--  Get our standard constants -->

<include name="constants.vbs"/>

<!--  Triggers  -->

<triggers>
  <trigger
   enabled="y"
   match="[CLAN]: *"
   name="ClanChan"
   script="ClanChan"
   sequence="100"
  >
  </trigger>
</triggers>

<!--  Aliases  -->

<aliases>
  <alias
   name="Showclan"
   script="Showclan"
   match="Showclan"
   enabled="y"
  >
  </alias>
  <alias
   name="Clanset"
   script="SetClanBuffer"
   match="Clanset *"
   enabled="y"
  >
  </alias>
</aliases>

<!--  Script  -->


<script>
<![CDATA[

sub ClanChan(tname, output, wilds)
  'First lets get the number of lines we are keeping.
  dim Keep
  Keep = world.getvariable("Keep")
  'Retrieve last traffic.
  dim Buffer
  Buffer = split(world.getvariable("ClanChan"),"^`")
  'Find a blank spot, if there is one.
  dim count, fnd
  fnd = -1
  for count = 0 to ubound(Buffer)
    if Buffer(count) = "-1" or Buffer(count) = "Empty" then
      fnd = count
      exit for
    end if
  next
  if fnd = -1 then
    'We already have the maximum, so shift them all and add the new on into
    'the last possition.
    for count = 1 to ubound(Buffer)
      Buffer(count - 1) = Buffer(count)
    next
    'Note: We use 'now' to get the time and date to time stamp it. ;)
    Buffer(ubound(Buffer)) = now & " [CLAN]: " & wilds(1)
  else
    'This is if we found a blank.
    Buffer(fnd) = now & " [CLAN]: " & wilds(1)
  end if
  world.setvariable "ClanChan", join(Buffer,"^`")
end sub

sub SetClanBuffer (aname, output, wilds)
  'We will need a new array for later, since split does not create one you can change the size of. :p
  dim Keep
  Keep = wilds(1)
  if isnumeric(Keep) then
    if Keep < 2 then
      world.note "Clan buffer cannot be less than two lines."
    else
      'Since arrays start at 0, we need one less than our setting or 10 lines would end up as 11.
      Keep = Keep - 1
      redim NewAr(Keep)
    end if
    'Retrieve last traffic.
    dim Buffer
    Buffer = split(world.getvariable("ClanChan"),"^`")
    if Keep > ubound(Buffer) then
      dim count
      'Put existing data in the new one.
      for count = 0 to ubound(Buffer)
        NewAr(count) = Buffer(count)
      next
      'Fill the rest.
      for count = ubound(Buffer) + 1 to Keep
        NewAr(count) = "-1"
      next
      world.setvariable "ClanChan", join(NewAr,"^`")
    else
      if Keep = ubound(Buffer) then
        world.note "New size for clan buffer is the same as last."
        world.note "Command ignored."
        exit sub
      end if
      dim count2, oldlen, strt
      oldlen = ubound(Buffer)
      strt = oldlen - Keep
      'Store what we can.
      for count2 =  strt to oldlen
        NewAr(count2 - strt) = Buffer(count2)
      next
      world.setvariable "ClanChan", join(NewAr,"^`")
    end if
    world.note Keep + 1 & " lines of clan messages will now be stored."
  else
    world.note "Must be a number! >" & Keep & "<"
  end if
  world.setvariable "Keep", Keep
end sub

sub ShowClan(aname, output, wilds)
  dim Buffer, count
  Buffer = split(world.getvariable("ClanChan"),"^`")
  for count = 0 to ubound(Buffer)
    if Buffer(count) <> "-1" then
      world.note Buffer(count)
    end if
  next
end sub

sub OnPluginInstall
  dim Keep
  Keep = world.getvariable("Keep")
  if isnumeric(Keep) and Keep > 0 then
    exit sub
  end if
  world.setvariable "Keep", "10"
  world.setvariable "ClanChan", "Empty^`-1^`-1^`-1^`-1^`-1^`-1^`-1^`-1^`-1"
end sub
]]>
</script>
</muclient>